[mikktspace] Initial port (#13900)

http://mikktspace.com/

ports/mikktspace/CMakeLists.txt

@@ -0,0 +1,41 @@
+cmake_minimum_required(VERSION 3.8)
+project(mikktspace C)
+
+set(CMAKE_DEBUG_POSTFIX d)
+
+add_library(${PROJECT_NAME} "")
+add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
+target_include_directories(
+	${PROJECT_NAME}
+	PUBLIC
+		$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+		$<INSTALL_INTERFACE:include>
+)
+
+target_sources(
+	${PROJECT_NAME}
+	PRIVATE
+		${CMAKE_CURRENT_SOURCE_DIR}/mikktspace.c
+)
+
+install(
+	TARGETS ${PROJECT_NAME}
+	EXPORT ${PROJECT_NAME}_target
+	ARCHIVE DESTINATION lib
+	LIBRARY DESTINATION lib
+	RUNTIME DESTINATION bin
+)
+
+if(NOT MIKKTSPACE_SKIP_HEADERS)
+    install(FILES
+        ${CMAKE_CURRENT_SOURCE_DIR}/mikktspace.h
+        DESTINATION include
+    )
+endif()
+
+install(
+	EXPORT ${PROJECT_NAME}_target
+	NAMESPACE ${PROJECT_NAME}::
+	FILE ${PROJECT_NAME}-config.cmake
+	DESTINATION share/${PROJECT_NAME}
+)

ports/mikktspace/CONTROL

@@ -0,0 +1,4 @@
+Source: mikktspace
+Version: 2020-10-06
+Homepage: https://github.com/mmikk/MikkTSpace
+Description: A common standard for tangent space used in baking tools to produce normal maps

ports/mikktspace/portfile.cmake

@@ -0,0 +1,23 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO mmikk/MikkTSpace
+    REF 3e895b49d05ea07e4c2133156cfa94369e19e409
+    SHA512 3ca433bd4efd0e048138f9efc5ba9021e4f3f78a535ea48733088ba5f43e60aad7f840f00e0597a0c053cda4776177bf6deb14cecf4d172b9b68acf00d5a1ca7
+    HEAD_REF master
+)
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt DESTINATION ${SOURCE_PATH})
+
+vcpkg_configure_cmake(
+    SOURCE_PATH ${SOURCE_PATH}
+    PREFER_NINJA
+    OPTIONS_DEBUG
+        -DMIKKTSPACE_SKIP_HEADERS=ON
+)
+
+vcpkg_install_cmake()
+vcpkg_fixup_cmake_targets()
+
+file(INSTALL ${SOURCE_PATH}/mikktspace.h DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT} RENAME copyright)