[lua] Test, revise (#49582)

2026-01-28 10:24:07 +01:00 · 2026-01-28 10:24:07 +01:00 · a1177241ef
parent 5d2b8a6efd
commit a1177241ef
21 changed files with 341 additions and 183 deletions
--- a/ports/lua/CMakeLists-cpp.txt
+++ b/ports/lua/CMakeLists-cpp.txt
@ -1,28 +0,0 @@
-SET(SRC_LIBLUACPP ${SRC_LIBLUA})
-ADD_LIBRARY ( lua-cpp ${SRC_LIBLUACPP} ${HDR_LIBLUACPP} )
-SET_TARGET_PROPERTIES(lua-cpp PROPERTIES OUTPUT_NAME "lua-c++")
-SET_SOURCE_FILES_PROPERTIES(${SRC_LIBLUACPP} PROPERTIES LANGUAGE CXX)
-TARGET_INCLUDE_DIRECTORIES(lua-cpp PRIVATE $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src> PUBLIC $<INSTALL_INTERFACE:include>)
-IF (BUILD_SHARED_LIBS AND WIN32)
-    TARGET_COMPILE_DEFINITIONS (lua-cpp PUBLIC -DLUA_BUILD_AS_DLL )
-ENDIF ()
-IF (UNIX)
-    IF (APPLE)
-        TARGET_COMPILE_DEFINITIONS (lua-cpp PUBLIC -DLUA_USE_DLOPEN)
-    ELSE ()
-        FIND_LIBRARY (LIB_DLOPEN NAMES dl)
-        IF (LIB_DLOPEN)
-            TARGET_COMPILE_DEFINITIONS (lua-cpp PUBLIC -DLUA_USE_DLOPEN)
-            TARGET_LINK_LIBRARIES (lua-cpp ${CMAKE_DL_LIBS})
-        ENDIF ()
-    ENDIF ()
-ENDIF ()
-
-INSTALL ( TARGETS lua-cpp
-    EXPORT unofficial-lua-cpp-config
-    RUNTIME DESTINATION bin
-    LIBRARY DESTINATION lib
-    ARCHIVE DESTINATION lib
-)
-
-INSTALL(EXPORT unofficial-lua-cpp-config DESTINATION share/unofficial-lua-cpp)
--- a/ports/lua/CMakeLists.txt
+++ b/ports/lua/CMakeLists.txt
@ -1,117 +1,142 @@
 # Lua can be compiled as either C or C++.
-# Default configuration is C, set COMPILE_AS_CPP to ON to use C++.
+# The vcpkg port always builds the lua C library.
+# Option COMPILE_AS_CPP enables building a lua-c++ library.
 # See http://stackoverflow.com/questions/13560945/c-and-c-library-using-longjmp for why would you want to do that.
 # Primary differences:
 # - Exceptions will be used instead of setjmp/longjmp
 # - The name mangling for functions will be C++ instead of C.
-#     - This is a source-incompatible change because extern "C" is chosen by the including application.
-# - The lua.hpp header will not be available.
+# The use of headers must match the selected library.
+# 'lua.hpp' can be used by C++ apps with the lua C library.
+# The other headers can be used
+# - by C apps with the lua C library
+# - by C++ apps with the lua C++ library
+# - by C++ apps with the lua C library only with explicit 'extern "C" ...'

-CMAKE_MINIMUM_REQUIRED(VERSION 3.18)
+cmake_minimum_required(VERSION 3.31)

-PROJECT(lua)
+option(COMPILE_AS_CPP "Enable the lua C++ library")
+option(INSTALL_TOOLS  "Install compiler and interpreter")

-# Build Libraries
-FILE(GLOB HDR_LIBLUA "${CMAKE_SOURCE_DIR}/src/*.h")
-# For luac.c
-LIST(REMOVE_ITEM HDR_LIBLUA "${CMAKE_SOURCE_DIR}/src/lopnames.h")
+project(lua)

-FILE(GLOB SRC_LIBLUA "${CMAKE_SOURCE_DIR}/src/*.c")
-# Executables luac and luai
-LIST(REMOVE_ITEM SRC_LIBLUA "${CMAKE_SOURCE_DIR}/src/luac.c" "${CMAKE_SOURCE_DIR}/src/lua.c")
+set(CMAKE_C_STANDARD 99)

-IF (WIN32)
-    # remove warnings
-    ADD_DEFINITIONS (-D_CRT_SECURE_NO_WARNINGS )
-ENDIF ()
+if(WIN32)
+    add_compile_definitions(_CRT_SECURE_NO_WARNINGS)
+endif()

-IF (UNIX)
-    ADD_DEFINITIONS (-DLUA_USE_POSIX)
-    FIND_LIBRARY (LIB_MATH NAMES m)
-ENDIF ()
+if(UNIX)
+    add_compile_definitions(LUA_USE_POSIX LUA_USE_DLOPEN)
+    find_library(HAVE_LIBM NAMES m)
+endif()
+
+set(SRC_LUAI "${PROJECT_SOURCE_DIR}/src/lua.c")
+set(SRC_LUAC "${PROJECT_SOURCE_DIR}/src/luac.c")
+file(GLOB SRC_LIBLUA "${PROJECT_SOURCE_DIR}/src/*.c")
+list(REMOVE_ITEM SRC_LIBLUA "${SRC_LUAI}" "${SRC_LUAC}")

 # C library
-SET (CMAKE_C_STANDARD 99)
-SET(SRC_LIBLUAC ${SRC_LIBLUA})
-ADD_LIBRARY ( lua ${SRC_LIBLUAC} ${HDR_LIBLUA} )
-TARGET_INCLUDE_DIRECTORIES(lua PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/src> PUBLIC $<INSTALL_INTERFACE:include>)
-SET_PROPERTY (TARGET lua PROPERTY POSITION_INDEPENDENT_CODE ON)
-SET_SOURCE_FILES_PROPERTIES(${SRC_LIBLUAC} PROPERTIES LANGUAGE C)

-IF (BUILD_SHARED_LIBS AND WIN32)
-    TARGET_COMPILE_DEFINITIONS (lua PUBLIC -DLUA_BUILD_AS_DLL )
-ENDIF ()
+add_library(lua ${SRC_LIBLUA})
+target_include_directories(lua PUBLIC
+    "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>"
+    $<INSTALL_INTERFACE:include>
+)

-IF (UNIX)
-    IF (APPLE)
-        TARGET_COMPILE_DEFINITIONS (lua PUBLIC -DLUA_USE_DLOPEN)
-    ELSE ()
-        FIND_LIBRARY (LIB_DLOPEN NAMES dl)
-        IF (LIB_DLOPEN)
-            TARGET_COMPILE_DEFINITIONS (lua PUBLIC -DLUA_USE_DLOPEN)
-            TARGET_LINK_LIBRARIES (lua ${CMAKE_DL_LIBS})
-        ENDIF ()
-        IF (LIB_MATH)
-            TARGET_LINK_LIBRARIES (lua m)
-        ENDIF ()
-    ENDIF ()
-ENDIF ()
+if(WIN32 AND BUILD_SHARED_LIBS)
+    target_compile_definitions(lua PUBLIC LUA_BUILD_AS_DLL)
+endif()

-INSTALL ( TARGETS lua
+if(UNIX)
+    target_link_libraries(lua PRIVATE ${CMAKE_DL_LIBS})
+    if(HAVE_LIBM)
+        target_link_libraries(lua PRIVATE m)
+    endif()
+endif()
+
+install(FILES src/lualib.h src/lua.h src/luaconf.h src/lauxlib.h src/lua.hpp
+    DESTINATION include
+)
+install(TARGETS lua
    EXPORT unofficial-lua-config
    RUNTIME DESTINATION bin
    LIBRARY DESTINATION lib
    ARCHIVE DESTINATION lib
 )

-install(EXPORT unofficial-lua-config DESTINATION share/unofficial-lua)
-
 # CXX library
-IF (COMPILE_AS_CPP)
-    ADD_SUBDIRECTORY(cpp)
-ENDIF()

-IF (INSTALL_TOOLS)
-    # compiler uses non-exported APIs, so must include sources directly.
-    ADD_EXECUTABLE ( luac ${CMAKE_SOURCE_DIR}/src/luac.c ${SRC_LIBLUA} ${CMAKE_SOURCE_DIR}/src/lopnames.h )
-    ADD_EXECUTABLE ( luai ${CMAKE_SOURCE_DIR}/src/lua.c )  # interpreter
-
-    TARGET_INCLUDE_DIRECTORIES(luac PRIVATE ${CMAKE_CURRENT_LIST_DIR}/src)
-    TARGET_LINK_LIBRARIES ( luai PRIVATE lua )
-    SET_TARGET_PROPERTIES ( luai PROPERTIES OUTPUT_NAME lua PDB_NAME luai )
-    IF (UNIX)
-        IF (CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
-            SET (_LIB_READLINE_NAME edit)
-        ELSE ()
-            SET (_LIB_READLINE_NAME readline)
-        ENDIF ()
-        FIND_LIBRARY (LIB_READLINE NAMES ${_LIB_READLINE_NAME})
-        IF (LIB_READLINE)
-            TARGET_COMPILE_DEFINITIONS (luai PUBLIC -DLUA_USE_READLINE)
-            TARGET_LINK_LIBRARIES(luai PRIVATE ${LIB_READLINE})
-            IF (_LIB_READLINE_NAME STREQUAL edit)
-                TARGET_INCLUDE_DIRECTORIES (luai PUBLIC /usr/include/edit)
-            ENDIF ()
-        ENDIF ()
-        
-        IF (LIB_MATH)
-            TARGET_LINK_LIBRARIES (luac m)
-        ENDIF ()
-    ENDIF ()
-    INSTALL ( TARGETS luai luac RUNTIME DESTINATION tools/lua )
-ENDIF ()
-
-IF (NOT SKIP_INSTALL_HEADERS)
-    INSTALL(
-        FILES
-            src/lualib.h
-            src/lua.h
-            src/luaconf.h
-            src/lauxlib.h
-        DESTINATION include
+if(COMPILE_AS_CPP)
+    # creating distinct source files with LANGUAGE CXX
+    file(MAKE_DIRECTORY "${PROJECT_BINARY_DIR}/cpp")
+    file(COPY ${SRC_LIBLUA} DESTINATION "${PROJECT_BINARY_DIR}/cpp")
+    file(GLOB SRC_LIBLUACPP "${PROJECT_BINARY_DIR}/cpp/*.c")
+    set_source_files_properties(${SRC_LIBLUACPP} PROPERTIES LANGUAGE CXX)
+    add_library(lua-cpp ${SRC_LIBLUACPP})
+    set_target_properties(lua-cpp PROPERTIES OUTPUT_NAME "lua-c++")
+    target_include_directories(lua-cpp PUBLIC
+        "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>"
+        $<INSTALL_INTERFACE:include>
    )
-    # If using C++, don't install extern "C" wrapper.
-    IF (NOT COMPILE_AS_CPP)
-        INSTALL(FILES src/lua.hpp DESTINATION include)
-    ENDIF ()
-ENDIF ()
+
+    if(WIN32 AND BUILD_SHARED_LIBS)
+        target_compile_definitions(lua-cpp PUBLIC LUA_BUILD_AS_DLL)
+    endif()
+
+    if(UNIX)
+        target_compile_definitions(lua-cpp PUBLIC LUA_USE_DLOPEN)
+        target_link_libraries(lua-cpp PRIVATE ${CMAKE_DL_LIBS})
+        if(HAVE_LIBM)
+            target_link_libraries(lua-cpp PRIVATE m)
+        endif()
+    endif()
+
+    install(TARGETS lua-cpp
+        EXPORT unofficial-lua-config
+        RUNTIME DESTINATION bin
+        LIBRARY DESTINATION lib
+        ARCHIVE DESTINATION lib
+    )
+endif()
+
+# tools
+
+if(INSTALL_TOOLS)
+    # The compiler uses non-exported APIs, so it cannot use the shared library
+    add_executable(luac "${SRC_LUAC}" $<TARGET_OBJECTS:lua>)
+    target_include_directories(luac PRIVATE "${PROJECT_SOURCE_DIR}/src")
+    if(UNIX AND HAVE_LIBM)
+        target_link_libraries(luac PRIVATE m)
+    endif()
+    
+    # The Interpreter
+    add_executable(luai "${SRC_LUAI}")
+    set_target_properties(luai PROPERTIES OUTPUT_NAME "lua" PDB_NAME "luai")
+    target_link_libraries(luai PRIVATE lua)
+    if(UNIX)
+        find_package(PkgConfig REQUIRED)
+        pkg_check_modules(PC_READLINE readline REQUIRED)
+        target_compile_definitions(luai PRIVATE LUA_USE_READLINE)
+        target_include_directories(luai PRIVATE ${PC_READLINE_INCLUDE_DIRS})
+        target_link_libraries(luai PRIVATE ${PC_READLINE_LINK_LIBRARIES})
+    endif()
+
+    install(TARGETS luai luac
+        DESTINATION bin
+    )
+endif()
+
+# unofficial config
+
+include(CMakePackageConfigHelpers)
+write_basic_package_version_file("${PROJECT_BINARY_DIR}/unofficial-lua-config-version.cmake"
+    VERSION "${VERSION}"
+    COMPATIBILITY "SameMajorVersion"
+)
+install(FILES "${PROJECT_BINARY_DIR}/unofficial-lua-config-version.cmake"
+    DESTINATION share/unofficial-lua
+)
+install(EXPORT unofficial-lua-config
+    NAMESPACE unofficial::lua::
+    DESTINATION share/unofficial-lua
+)
--- a/ports/lua/COPYRIGHT
+++ b/ports/lua/COPYRIGHT
@ -1,6 +0,0 @@
-Copyright © 1994–2016 Lua.org, PUC-Rio.
-Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
-
-The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
-
-THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
--- a/ports/lua/portfile.cmake
+++ b/ports/lua/portfile.cmake
@ -9,46 +9,49 @@ vcpkg_extract_source_archive(
    PATCHES
        vs2015-impl-c99.patch
        fix-ios-system.patch
+        uwp-no-popen.diff
 )
-
 file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
-file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/CMakeLists-cpp.txt" DESTINATION "${SOURCE_PATH}/cpp" RENAME "CMakeLists.txt")
+
+if(NOT VCPKG_TARGET_IS_WINDOWS)
+    vcpkg_find_acquire_program(PKGCONFIG)
+    set(ENV{PKG_CONFIG} "${PKGCONFIG}")
+endif()

 vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
-  FEATURES
-    cpp COMPILE_AS_CPP # Also used in cmake wrapper
-    tools INSTALL_TOOLS
+    FEATURES
+        cpp     COMPILE_AS_CPP
+        tools   INSTALL_TOOLS
 )

 vcpkg_cmake_configure(
    SOURCE_PATH "${SOURCE_PATH}"
    OPTIONS
-         ${FEATURE_OPTIONS}
+        ${FEATURE_OPTIONS}
+        -DVERSION=${VERSION}
    OPTIONS_DEBUG
-        -DSKIP_INSTALL_HEADERS=ON
+        -DINSTALL_TOOLS=OFF
 )
 vcpkg_cmake_install()
-
 vcpkg_copy_pdbs()
-
 vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-lua CONFIG_PATH share/unofficial-lua)

-if("cpp" IN_LIST FEATURES)
-    vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-lua-cpp CONFIG_PATH "share/unofficial-lua-cpp")
+if("tools" IN_LIST FEATURES)
+    vcpkg_copy_tools(TOOL_NAMES lua luac  AUTO_CLEAN)
 endif()

-if ("tools" IN_LIST FEATURES)
-    vcpkg_copy_tools(TOOL_NAMES lua luac SEARCH_DIR "${CURRENT_PACKAGES_DIR}/tools/${PORT}")
+if(VCPKG_TARGET_IS_WINDOWS AND VCPKG_LIBRARY_LINKAGE STREQUAL "dynamic")
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/luaconf.h" "defined(LUA_BUILD_AS_DLL)" "1")
 endif()

-if(VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)
-    if(VCPKG_TARGET_IS_WINDOWS)
-        vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/luaconf.h" "defined(LUA_BUILD_AS_DLL)" "1")
-    endif()
-endif()
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")

-# Suitable for old version
-configure_file("${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake.in"  "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
 file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")

-file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/COPYRIGHT" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+file(READ "${SOURCE_PATH}/doc/readme.html" readme)
+string(REGEX REPLACE "^.*<H2><A NAME=\"license\">License</A></H2>" "" license "${readme}")
+string(REGEX REPLACE [[<A HREF="([^"]+)">([^<]*)</A>]] "\\2 [\\1]" license "${license}")
+string(REGEX REPLACE "<[^>]*>" "" license "${license}")
+string(REGEX REPLACE "\n\n+" "\n\n" license "${license}")
+file(WRITE "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright" "${license}")
--- a/ports/lua/usage
+++ b/ports/lua/usage
@ -1,5 +1,10 @@
-Use this package via the module FindLua that comes with CMake. To use in your CMakeLists.txt:
+lua provides CMake integration for the C library:

-    find_package(Lua REQUIRED)
-    target_include_directories(main PRIVATE ${LUA_INCLUDE_DIR})
-    target_link_libraries(main PRIVATE ${LUA_LIBRARIES})
+  find_package(Lua REQUIRED)
+  target_include_directories(main PRIVATE ${LUA_INCLUDE_DIR})
+  target_link_libraries(main PRIVATE ${LUA_LIBRARIES})
+
+lua[cpp] provides a C++ library with exception handling:
+
+  find_package(unofficial-lua)
+  target_link_libraries(main PRIVATE unofficial::lua::lua-cpp)
--- a/ports/lua/uwp-no-popen.diff
+++ b/ports/lua/uwp-no-popen.diff
@ -0,0 +1,24 @@
+diff --git a/src/liolib.c b/src/liolib.c
+index 57615e6..70e5899 100644
+--- a/src/liolib.c
+++ b/src/liolib.c
+@@ -23,6 +23,9 @@
+ #include "lualib.h"
+ #include "llimits.h"
+ 
+#if defined(_WIN32)
+#include <winapifamily.h>
+#endif
+ 
+ /*
+ ** Change this macro to accept other modes for 'fopen' besides
+@@ -58,7 +61,8 @@ static int l_checkmode (const char *mode) {
+ #define l_popen(L,c,m)		(fflush(NULL), popen(c,m))
+ #define l_pclose(L,file)	(pclose(file))
+ 
+-#elif defined(LUA_USE_WINDOWS)	/* }{ */
+#elif defined(LUA_USE_WINDOWS)	/* }{ */ \
+      && !(defined(WINAPI_FAMILY_PARTITION) && WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP))
+ 
+ #define l_popen(L,c,m)		(_popen(c,m))
+ #define l_pclose(L,file)	(_pclose(file))
--- a/ports/lua/vcpkg-cmake-wrapper.cmake
+++ b/ports/lua/vcpkg-cmake-wrapper.cmake
@ -0,0 +1,15 @@
+# Not using/wrapping FindLua.cmake because
+# it poorly handles new Lua versions and multi-config.
+_find_package(${ARGS} NAMES unofficial-lua)
+if(Lua_FOUND)
+    get_filename_component(LUA_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}" PATH)
+    get_filename_component(LUA_INCLUDE_DIR "${LUA_INCLUDE_DIR}" PATH)
+    set(LUA_INCLUDE_DIR ${LUA_INCLUDE_DIR}/include)
+    set(LUA_LIBRARIES unofficial::lua::lua)
+    # deprecated vars
+    set(LUA_FOUND 1)
+    set(LUA_VERSION_STRING "${Lua_VERSION}")
+    set(LUA_VERSION_MAJOR "${Lua_VERSION_MAJOR}")
+    set(LUA_VERSION_MINOR "${Lua_VERSION_MINOR}")
+    set(LUA_VERSION_PATCH "${Lua_VERSION_PATCH}")
+endif()
--- a/ports/lua/vcpkg-cmake-wrapper.cmake.in
+++ b/ports/lua/vcpkg-cmake-wrapper.cmake.in
@ -1,23 +0,0 @@
-set(REQUIRES )
-foreach(ARG IN_LISTS ${ARGS})
-    if (ARG STREQUAL "REQUIRED")
-        set(REQUIRES "REQUIRED")
-    endif()
-endforeach()
-
-_find_package(unofficial-lua CONFIG ${REQUIRES})
-
-if (@COMPILE_AS_CPP@)
-    _find_package(unofficial-lua-cpp CONFIG ${REQUIRES})
-endif()
-
-get_filename_component(LUA_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}" PATH)
-get_filename_component(LUA_INCLUDE_DIR "${LUA_INCLUDE_DIR}" PATH)
-set(LUA_INCLUDE_DIR ${LUA_INCLUDE_DIR}/include)
-
-list(APPEND LUA_LIBRARIES lua)
-if (TARGET lua-cpp)
-    list(APPEND LUA_LIBRARIES lua-cpp)
-endif()
-
-set(LUA_FOUND 1)
--- a/ports/lua/vcpkg.json
+++ b/ports/lua/vcpkg.json
@ -1,9 +1,10 @@
 {
  "name": "lua",
  "version": "5.5.0",
+  "port-version": 1,
  "description": "A powerful, fast, lightweight, embeddable scripting language",
  "homepage": "https://www.lua.org",
-  "license": null,
+  "license": "MIT",
  "dependencies": [
    {
      "name": "vcpkg-cmake",
@ -16,12 +17,17 @@
  ],
  "features": {
    "cpp": {
-      "description": "Builds Lua for C++ linkage",
-      "supports": "!uwp"
+      "description": "Builds Lua for C++ linkage"
    },
    "tools": {
      "description": "Builds Lua compiler and interpreter",
-      "supports": "!ios"
+      "supports": "!ios",
+      "dependencies": [
+        {
+          "name": "readline-unix",
+          "platform": "!windows"
+        }
+      ]
    }
  }
 }
--- a/ports/sproto/CMakeLists.txt
+++ b/ports/sproto/CMakeLists.txt
@ -3,7 +3,7 @@ project(sproto C)

 set(CMAKE_C_STANDARD 99)

-find_package(unofficial-lua CONFIG REQUIRED)
+find_package(Lua REQUIRED)

 add_library(sproto sproto.c lsproto.c)

@ -17,7 +17,7 @@ else()
    target_compile_definitions(sproto PUBLIC SPROTO_STATIC)
 endif()

-target_link_libraries(sproto PRIVATE lua)
+target_link_libraries(sproto PRIVATE ${LUA_LIBRARIES})

 target_include_directories(sproto PRIVATE ${LUA_INCLUDE_DIR})

--- a/ports/sproto/sproto-config.cmake.in
+++ b/ports/sproto/sproto-config.cmake.in
@ -1,7 +1,7 @@
@PACKAGE_INIT@

 include(CMakeFindDependencyMacro)
-find_dependency(unofficial-lua CONFIG)
+find_dependency(Lua)

 include("${CMAKE_CURRENT_LIST_DIR}/sproto-targets.cmake")

--- a/ports/sproto/vcpkg.json
+++ b/ports/sproto/vcpkg.json
@ -1,6 +1,7 @@
 {
  "name": "sproto",
  "version-date": "2024-07-08",
+  "port-version": 1,
  "description": "Yet another protocol library like google protocol buffers, but simple and fast",
  "homepage": "https://github.com/cloudwu/sproto",
  "license": "MIT",
--- a/scripts/test_ports/cmake-user/vcpkg.json
+++ b/scripts/test_ports/cmake-user/vcpkg.json
@ -125,6 +125,10 @@
          "default-features": false,
          "platform": "!uwp & !mingw"
        },
+        {
+          "$package": "Lua",
+          "name": "lua"
+        },
        {
          "$package": "Curses",
          "name": "ncurses",
--- a/scripts/test_ports/vcpkg-ci-lua/portfile.cmake
+++ b/scripts/test_ports/vcpkg-ci-lua/portfile.cmake
@ -0,0 +1,32 @@
+set(VCPKG_POLICY_EMPTY_PACKAGE enabled)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${CURRENT_PORT_DIR}/project"
+    OPTIONS
+        "-DFEATURES=${FEATURES}"
+)
+vcpkg_cmake_install()
+
+if("run-programs" IN_LIST FEATURES)
+    # lua executable"
+    message(STATUS "Running lua")
+    vcpkg_execute_required_process(
+        COMMAND "${CURRENT_INSTALLED_DIR}/tools/lua/lua" -e "print(package.path)"
+        WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}"
+        LOGNAME execute-lua-${TARGET_TRIPLET}
+    )
+    # user executable (this port)
+    if(CMAKE_HOST_WIN32)
+        vcpkg_host_path_list(PREPEND ENV{PATH} "${CURRENT_INSTALLED_DIR}/bin")
+    elseif(CMAKE_HOST_APPLE)
+         vcpkg_host_path_list(PREPEND ENV{DYLD_LIBRARY_PATH} "${CURRENT_INSTALLED_DIR}/lib")
+    else()
+         vcpkg_host_path_list(PREPEND ENV{LD_LIBRARY_PATH} "${CURRENT_INSTALLED_DIR}/lib")
+    endif()
+    message(STATUS "Running main")
+    vcpkg_execute_required_process(
+        COMMAND "${CURRENT_PACKAGES_DIR}/bin/${PORT}/main"
+        WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}"
+        LOGNAME execute-main-${TARGET_TRIPLET}
+    )
+endif()
--- a/scripts/test_ports/vcpkg-ci-lua/project/CMakeLists.txt
+++ b/scripts/test_ports/vcpkg-ci-lua/project/CMakeLists.txt
@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.16)
+project(lua-test C CXX)
+
+find_package(Lua REQUIRED)
+
+add_executable(main main.c)
+target_include_directories(main PRIVATE ${LUA_INCLUDE_DIR})
+target_link_libraries(main PRIVATE ${LUA_LIBRARIES})
+install(TARGETS main RUNTIME DESTINATION bin/vcpkg-ci-lua)
+
+if("cpp" IN_LIST FEATURES)
+    find_package(unofficial-lua REQUIRED)
+
+    add_executable(main-cpp main.cpp)
+    target_link_libraries(main-cpp PRIVATE unofficial::lua::lua-cpp)
+endif()
--- a/scripts/test_ports/vcpkg-ci-lua/project/main.c
+++ b/scripts/test_ports/vcpkg-ci-lua/project/main.c
@ -0,0 +1,23 @@
+#include <stdio.h>
+
+#include <lua.h>
+#include <lualib.h>
+#include <lauxlib.h>
+
+int main()
+{
+    lua_State* L = luaL_newstate();
+    if (L == NULL) {
+        printf("luaL_newstate failed\n");
+        return 2;
+    }
+
+    luaL_openlibs(L);
+
+    if (luaL_dostring(L, "print(package.path)") == LUA_OK) {
+        lua_pop(L, lua_gettop(L));
+    }
+
+    lua_close(L);
+    return 0;
+}
--- a/scripts/test_ports/vcpkg-ci-lua/project/main.cpp
+++ b/scripts/test_ports/vcpkg-ci-lua/project/main.cpp
@ -0,0 +1,2 @@
+/* for compilation as C++ and linking with lua-c++ */
+#include "main.c"
--- a/scripts/test_ports/vcpkg-ci-lua/vcpkg.json
+++ b/scripts/test_ports/vcpkg-ci-lua/vcpkg.json
@ -0,0 +1,49 @@
+{
+  "name": "vcpkg-ci-lua",
+  "version-string": "ci",
+  "description": "Validate port lua",
+  "dependencies": [
+    {
+      "name": "lua",
+      "default-features": false
+    },
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    }
+  ],
+  "default-features": [
+    "cpp",
+    {
+      "$comment": "The platform expression is tuned for vcpkg CI.",
+      "name": "run-programs",
+      "platform": "native | (!android & !uwp & !arm64)"
+    }
+  ],
+  "features": {
+    "cpp": {
+      "description": "Test the C++ library",
+      "dependencies": [
+        {
+          "name": "lua",
+          "default-features": false,
+          "features": [
+            "cpp"
+          ]
+        }
+      ]
+    },
+    "run-programs": {
+      "description": "Run lua and user program",
+      "dependencies": [
+        {
+          "name": "lua",
+          "default-features": false,
+          "features": [
+            "tools"
+          ]
+        }
+      ]
+    }
+  }
+}
--- a/versions/baseline.json
+++ b/versions/baseline.json
@ -6090,7 +6090,7 @@
    },
    "lua": {
      "baseline": "5.5.0",
-      "port-version": 0
+      "port-version": 1
    },
    "lua-compat53": {
      "baseline": "0.10",
@ -9406,7 +9406,7 @@
    },
    "sproto": {
      "baseline": "2024-07-08",
-      "port-version": 0
+      "port-version": 1
    },
    "sprout": {
      "baseline": "2019-06-20",
--- a/versions/l-/lua.json
+++ b/versions/l-/lua.json
@ -1,5 +1,10 @@
 {
  "versions": [
+    {
+      "git-tree": "6767a2f27deb2b906d4353bd91c9bd26b30a7cf1",
+      "version": "5.5.0",
+      "port-version": 1
+    },
    {
      "git-tree": "68062c242e90605fcdab46f73a6cad3e93eab06b",
      "version": "5.5.0",
--- a/versions/s-/sproto.json
+++ b/versions/s-/sproto.json
@ -1,5 +1,10 @@
 {
  "versions": [
+    {
+      "git-tree": "49536a008ea0d9f5d102e82db105769128a70194",
+      "version-date": "2024-07-08",
+      "port-version": 1
+    },
    {
      "git-tree": "a13ca7a665693b716b040d84c0592f3aec0aef8d",
      "version-date": "2024-07-08",