mirror of https://github.com/microsoft/vcpkg.git
98 lines
3.9 KiB
CMake
98 lines
3.9 KiB
CMake
if(VCPKG_TARGET_IS_WINDOWS)
|
|
vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
|
|
endif()
|
|
|
|
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO open-telemetry/opentelemetry-cpp
|
|
REF "v${VERSION}"
|
|
SHA512 4f8a19a486620b9daeb110da09b5d412ef8372d152a8c8d6242e9af39e4acfd12599e85d7038dd0bd74238c9a54f85ca3acd04cec252573d5c134674a7198170
|
|
HEAD_REF main
|
|
PATCHES
|
|
fix-target_link.patch
|
|
)
|
|
|
|
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
|
|
FEATURES
|
|
etw WITH_ETW
|
|
zipkin WITH_ZIPKIN
|
|
prometheus WITH_PROMETHEUS
|
|
elasticsearch WITH_ELASTICSEARCH
|
|
otlp-file WITH_OTLP_FILE
|
|
otlp-http WITH_OTLP_HTTP
|
|
otlp-grpc WITH_OTLP_GRPC
|
|
geneva WITH_GENEVA
|
|
user-events WITH_USER_EVENTS
|
|
opentracing WITH_OPENTRACING
|
|
INVERTED_FEATURES
|
|
user-events BUILD_TRACEPOINTS
|
|
)
|
|
|
|
# opentelemetry-proto is a third party submodule and opentelemetry-cpp release did not pack it.
|
|
if(WITH_OTLP_FILE OR WITH_OTLP_GRPC OR WITH_OTLP_HTTP)
|
|
set(OTEL_PROTO_VERSION "1.8.0")
|
|
vcpkg_download_distfile(ARCHIVE
|
|
URLS "https://github.com/open-telemetry/opentelemetry-proto/archive/v${OTEL_PROTO_VERSION}.tar.gz"
|
|
FILENAME "opentelemetry-proto-${OTEL_PROTO_VERSION}.tar.gz"
|
|
SHA512 43e320c365f73e1302951cf69e4f395c8dec9fe3efba802dea10637b61721a64868fb0a45c33d2ac15f99a7ba0b865c268d268a543a4efeff10f5c59407e7ba9
|
|
)
|
|
|
|
vcpkg_extract_source_archive(src ARCHIVE "${ARCHIVE}")
|
|
file(REMOVE_RECURSE "${SOURCE_PATH}/third_party/opentelemetry-proto")
|
|
file(COPY "${src}/." DESTINATION "${SOURCE_PATH}/third_party/opentelemetry-proto")
|
|
# Create empty .git directory to prevent opentelemetry from cloning it during build time
|
|
file(MAKE_DIRECTORY "${SOURCE_PATH}/third_party/opentelemetry-proto/.git")
|
|
list(APPEND FEATURE_OPTIONS "-DgRPC_CPP_PLUGIN_EXECUTABLE=${CURRENT_HOST_INSTALLED_DIR}/tools/grpc/grpc_cpp_plugin${VCPKG_HOST_EXECUTABLE_SUFFIX}")
|
|
endif()
|
|
list(APPEND FEATURE_OPTIONS -DCMAKE_CXX_STANDARD=14)
|
|
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "OFF")
|
|
|
|
if(WITH_GENEVA OR WITH_USER_EVENTS)
|
|
# Geneva and user events exporters from opentelemetry-cpp-contrib are tightly coupled with opentelemetry-cpp repo,
|
|
# so they should be ported as a feature under opentelemetry-cpp.
|
|
clone_opentelemetry_cpp_contrib(CONTRIB_SOURCE_PATH)
|
|
|
|
if(WITH_GENEVA)
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "${CONTRIB_SOURCE_PATH}/exporters/geneva")
|
|
if(VCPKG_TARGET_IS_WINDOWS)
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "${OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS}\;${CONTRIB_SOURCE_PATH}/exporters/geneva-trace")
|
|
else()
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "${OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS}\;${CONTRIB_SOURCE_PATH}/exporters/fluentd")
|
|
endif()
|
|
endif()
|
|
|
|
if(WITH_USER_EVENTS)
|
|
if(WITH_GENEVA)
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "${OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS}\;${CONTRIB_SOURCE_PATH}/exporters/user_events")
|
|
else()
|
|
set(OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS "${CONTRIB_SOURCE_PATH}/exporters/user_events")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
OPTIONS
|
|
-DBUILD_TESTING=OFF
|
|
-DWITH_EXAMPLES=OFF
|
|
-DOPENTELEMETRY_INSTALL=ON
|
|
-DWITH_BENCHMARK=OFF
|
|
-DOPENTELEMETRY_EXTERNAL_COMPONENT_PATH=${OPENTELEMETRY_CPP_EXTERNAL_COMPONENTS}
|
|
${FEATURE_OPTIONS}
|
|
MAYBE_UNUSED_VARIABLES
|
|
WITH_GENEVA
|
|
WITH_USER_EVENTS
|
|
BUILD_TRACEPOINTS
|
|
gRPC_CPP_PLUGIN_EXECUTABLE
|
|
)
|
|
|
|
vcpkg_cmake_install()
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH "lib/cmake/${PORT}")
|
|
vcpkg_copy_pdbs()
|
|
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/opentelemetry/sdk/configuration")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
|
|
vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")
|